Hàm Kiểu Bảng trong Sql Server

--ví dụ 1
USE AdventureWorks
GO
CREATE FUNCTION dbo.fn_ProductInfoByModelID(@p INT) RETURNS TABLE
AS
RETURN
 SELECT P.ProductID, P.Name, P.ProductNumber
 FROM Production.Product P 
 WHERE P.ProductModelID = @p
GO
-- gọi hàm trực tiếp
SELECT * FROM dbo.fn_ProductInfoByModelID(5)
 
--hoặc join với hàm
SELECT TH.*, P.Name
FROM Production.TransactionHistory TH
JOIN dbo.fn_ProductInfoByModelID(5) P ON TH.ProductID = P.ProductID

--ví dụ 2
CREATE FUNCTION dbo.fnCSVStr2Table(@CSVStr VARCHAR(8000)) 
RETURNS @Tbl TABLE (ValueColumn VARCHAR(1000))
AS
BEGIN
 DECLARE @SubStr VARCHAR(100), @i INT
 
 SET @i = CHARINDEX(',', @CSVStr, 0)
 WHILE @i > 0
 BEGIN
  SET @SubStr = LEFT(@CSVStr,@i-1)
  INSERT INTO @Tbl
  SELECT @SubStr
 
  SET @CSVStr = SUBSTRING(@CSVStr, @i+1,8000)
  SET @i = CHARINDEX(',', @CSVStr, 0)
 END 
 
 INSERT INTO @Tbl
 SELECT LTRIM(RTRIM(@CSVStr))
 
 RETURN
END

Khác biệt giữa hàm in-line và hàm multi-statement

Ví dụ

--ví dụ 3
SELECT TH.*, P.Name
FROM Production.TransactionHistory TH
JOIN dbo.fn_ProductInfoByModelID(5) P ON TH.ProductID = P.ProductID

Bạn có thể thấy không có bước gọi đến hàm mà là hai bước Clustered Index Scan trên hai bảng và sau đó là Hash Match, giống như câu lệnh JOIN trực tiếp giữa hai bảng. Phương án thực thi này giống hệt với khi bạn thực hiện câu lệnh:

--ví dụ 4
SELECT *
FROM Production.TransactionHistory TH
JOIN Production.Product P ON TH.ProductID = P.ProductID
WHERE P.ProductModelID = 5

--ví dụ 5
CREATE FUNCTION dbo.fn_ProductInfoByModelID_MSTV(@p INT) 
RETURNS @t TABLE(ProductID INT, Name NVARCHAR(50), ProductNumber NVARCHAR(25))
AS
BEGIN
 INSERT INTO @t
 SELECT P.ProductID, P.Name, P.ProductNumber
 FROM Production.Product P 
 WHERE P.ProductModelID = @p
 
 RETURN
END

--ví dụ 6
SELECT *
FROM Production.TransactionHistory TH
JOIN dbo.fn_ProductInfoByModelID_MSTV(5) P ON TH.ProductID = P.ProductID

Bây giờ bước thực hiện hàm đã trở thành một bước độc lập (trên cùng bên trái), và chi phí của nó được gán là 0% vì bộ Optimizer không có tí thông tin nào về bên trong của hàm. Khỏi cần nói phương án thực thi giờ đã trở nên rườm rà như thế nào. Và đây là thống kê vào/ra của hai lệnh gọi hàm:
Lệnh gọi hàm in-line (ví dụ 5):

Kết luận